Android Scoped Storage and Intent-Based Mechanism Implementation

Berton77

I'm trying to save my bitmapdata as png to local folder on Android, and I can't get it to work. I do get the window with folder selection and ability to give permision, but as soon as I do that, I get another selection, but this time for a file. If I select any file or go back to the app I get 'save failed' message. Any ideas?

 private function saveHandler(e: MouseEvent): void {
    // get drawing as bitmapdata from the canvas instance.
    var canvasBmp:BitmapData = canvas.drawing();

    // create new png encoder object and convert bitmapdata to png
    pngStream = PNGEncoder.encode(canvasBmp);

    // dispose of the bitmapdata object when finished.
    canvasBmp.dispose();

    // Use intent-based mechanism to select a directory to save the file
    selectedDirectory = new File();
    selectedDirectory.addEventListener(Event.SELECT, onSaveDirectorySelected);
    selectedDirectory.browseForDirectory("Select Directory to Save");
}
	
	private function onSaveDirectorySelected(event:Event):void {
		
	selectedDirectory.removeEventListener(Event.SELECT, onSaveDirectorySelected);

    // Get selected directory and request write permission
    selectedDir = event.target as File;
    selectedDir.addEventListener(PermissionEvent.PERMISSION_STATUS, onPermissionStatus);
    selectedDir.requestPermission();

    // Construct file name with timestamp
    var currentDate:Date = new Date();
    var dateString:String = currentDate.fullYear + "_" + (currentDate.month + 1) + "_" + currentDate.date;
    var timeString:String = currentDate.hours + "" + currentDate.minutes + "" + currentDate.seconds;
    fileName = "my image " + dateString + " " + timeString + ".png";

		
	}

   private function onPermissionStatus(e: PermissionEvent): void {
    if (e.status == PermissionStatus.GRANTED) {
        var file:File = selectedDir.resolvePath(fileName);
        var stream:FileStream = new FileStream();
        stream.open(file, FileMode.WRITE);
        stream.writeBytes(pngStream);
        stream.close();`

        // Remove text from log.text after 3s.
        log.text = "Image saved";
        timer = new Timer(3000, 1);
        timer.addEventListener(TimerEvent.TIMER, removeText);
        timer.start();
    } else {
        log.text = "Save failed";

        // Remove text from log.text after 3s.
        timer = new Timer(3000, 1);
        timer.addEventListener(TimerEvent.TIMER, removeText);
        timer.start();
    }
    }

pol2095

You can use my ANE Storage Access Framework (documentation), it's necessary to open the file explorer the first time to save a file, it's the new Android's behavior.
SAF doesn't need permission to work.

Berton77

pol2095 When I test your ANE I get a strange server popup address request during splashscreen.

Balkrishna

pol2095

Can you share the file to save using saf.ane saving the text file in android internal (File.documentDirectory.resolvePath("")).

pol2095

It's strange, can you share a screenshot, the code are you using, app descriptor, Air SDK version, Android version, debug or release mode, and phone model ?
No instance of the ANE is created during splashscreen .

Berton77

pol2095 I re-exported the apk and isntalled it on an android 13 device using AIR 50.2.2.4 and everything seems to be in order. I have no idea what that popup was about since it was a test app that just saves a bitmap of a square to device's internal storage after a button is pressed. My only problem now is that my saved .png files are blank when I open them. I'm not sure if I need to apply some encoding to fix this.

I'm trying to save a red square to Android device's storage, and this is what I have when a button is pressed:

// Create a BitmapData object for a red square
var bmd:BitmapData = new BitmapData(50, 50, false, 0xFF0000);

// Create a ByteArray and write the pixel data to it
var bytes:ByteArray = new ByteArray();
bytes.writeBytes(bmd.getPixels(bmd.rect));
bytes.position = 0;	
			
Document.createBytes("test.png", bytes, "image/*");

pol2095

you need to encode the BitmapData to PNG :

// Create a BitmapData object for a red square
var bmd:BitmapData = new BitmapData(50, 50, false, 0xFF0000);

// Create a ByteArray and encode to PNG
var bytes:ByteArray = new ByteArray(); 
bmd.encode( bmd.rect, new PNGEncoderOptions(), bytes );

Document.createBytes("test.png", bytes, "image/*");

Berton77

pol2095 Thanks a lot. This ane is a lifesaver, and it works seemlessly in comparison to the stock AIR library.

pol2095

Balkrishna
My SAF ANE doesn't support File class.
You can save text file like this :

import com.nativeExtensions.saf.Document;
import com.nativeExtensions.saf.DocumentEvent;

var content:String = "Save my text";
var document:Document = new Document();
document.addEventListener(DocumentEvent.EDIT, onEdit);
document.uri = document.documentsUri;
document.create("testFile.txt", content, "text/plain");

private function onEdit(event:DocumentEvent):void
{
	trace( event.uri );
}

Balkrishna

Above code open the intent to save the file and location in android.
My requirement is the client will tap the button which able to download the file from server without prompt/intent. After download client will able to play the content with tapping play button.

pol2095

It's not possible using SAF (it's a security behavior), it's necessary to launch the first time prompt/intent, it work like a permission (persistable Uri).
You can save the file in File.applicationStorageDorectory ?

Balkrishna

pol2095

I will brief the situation of the app requirement.
Below is the code for the final requirement functioning call.

function saveFile(fFile) {
    var usrDeviceIDStream = new FileStream();
    var usrDeviceIDFile: File = fFile.resolvePath("id.txt");
    usrDeviceIDStream.open(usrDeviceIDFile, FileMode.WRITE);
    usrDeviceIDStream.writeUTFBytes("File from as3");
    usrDeviceIDStream.close();
}

App required the internal path of the mobile as direct File.documentsDirectory.resolvePath("loc") will not work so I used :

var vFile:File = new File();
var data;
function fileAccessCheck() {
      vFile.addEventListener(Event.SELECT, dirSelect);
      vFile.browseForDirectory("Select the Directory");
      data = vFile.url;
}

So I saved the vFile.url into the File.applicationStorageDirectory.resolvePath("fileLoc.txt");

var sFile:File = File.applicationStorageDirectory.resolvePath("fileLoc.txt");
var sFileStream:FileStream = new FileStream();
sFileStream.open(sFile, FileMode.WRITE);
sFileStream.writeUTFBytes(data);   // data has content of vFile.url
sFileStream.close();
saveFile(vFile);

When I recheck the to saved file :

function fileCheck() {
        var sFile:File = File.applicationStorageDirectory.resolvePath("fileLoc.txt");
        var sFileStream:FileStream = new FileStream();
        if (sFile.exists) {
	        sFileStream.open(sFile, FileMode.READ);
	        var str = sFileStream.readUTFBytes(sFileStream.bytesAvailable);
	        pFile.nativePath = str;
	        saveFile(pFile);
        } else {
	        fileAccessCheck();
        }
}

Even if I change the url to the native path we get error :

ArgumentError: Error #2004: One of the parameters is invalid.
	at Error$/throwError()
	at flash.filesystem::File/set nativePath()
	at Function/file1_fla:MainTimeline/but2Fn/file1_fla:fileCheck()[file1_fla.MainTimeline::frame1:20]
	at file1_fla::MainTimeline/but2Fn()[file1_fla.MainTimeline::frame1:11]

I also sharing the final file please check. While debugging in animate CC, there is one button in center and then first click we get the intent from browse for directory. Then is saved the location of the browsed directory's url to the app storage directory. When again click to the same button then it get break the script.

File below for reference :
https://drive.google.com/file/d/13wAlAtkwIOtX47cCZ0DrrFWqa-Yv5vLV/view?usp=sharing

pol2095

This line is strange
pFile.nativePath = str;
the file content is a File.nativePath ?

Balkrishna

While getting permission to any folder using intent, I used vFile.browseForDirectory("select the directory") then when end user's device intent to select the folder for permission and then after allowed the end user, the given permission to object vFile.native path is saved to the text file. When app is relaunched will check the text file is available, if available then load the text file content/data. The content/data of text file is again assign to the pFile object using pFile.nativePath = str.

pol2095

using SAF, you can try :

import com.nativeExtensions.saf.Document;
import com.nativeExtensions.saf.DocumentEvent;

var document:Document = new Document();
document.addEventListener(DocumentEvent.READ, onRead);
document.uri = document.documentsUri;
document.getUriFromDir(true);

private function onRead(event:DocumentEvent):void
{
	var content:String = "Save my text";
	document.createFromUri("testFile.txt", content);
	trace( document.uri );
}

Boc89

Hello,
Thanks for sharing!
I'm trying to use on ane, but I'm having trouble.
I'm making an app for android, and I need to save files (text and xml) in an external folder, for example Documents.
So when the app starts, I try to get the URI and store it in an SO, as I saw in one of your posts :

var document: Document = new Document();
var mySO: SharedObject = SharedObject.getLocal("saf");
if (mySO.data.hasOwnProperty("documentsUri")) {
		if (mySO.data.documentsUri) {
			document.uri = mySO.data.documentsUri;
		}
		//ok, let's go
	} else {
              document.addEventListener(DocumentEvent.READ, onRead);
	     document.getUriFromDir(true);
	}
function onRead(event: DocumentEvent): void {
	mySO.data.documentsUri = event.uri;
	document.uri = mySO.data.documentsUri;
	mySO.flush();;
	//ok; let's go
}
//test for write a file
document.addEventListener(DocumentEvent.READ, onRead2);
	
	function onRead2(event: DocumentEvent): void {
		var content: String = "Save my text";
		document.createFromUri("testFile6.txt", content);
	}

Doesn't work... can you help me please ?

pol2095

I don't understand why are-you using twice DocumentEvent.READ listener ?
try this :

var document: Document = new Document();
var mySO: SharedObject = SharedObject.getLocal("saf");
if (mySO.data.hasOwnProperty("documentsUri")) {
	if (mySO.data.documentsUri) {
		document.uri = mySO.data.documentsUri;
	}
	//ok, let's go
} else {
    document.addEventListener(DocumentEvent.READ, onRead);
    document.getUriFromDir(true);
}

function onRead(event: DocumentEvent): void {
	document.removeEventListener(DocumentEvent.READ, onRead);
	trace( event.uri );
	mySO.data.documentsUri = event.uri;
	document.uri = mySO.data.documentsUri;
	mySO.flush();
	
	var content: String = "Save my text";
	var filename:String = "testFile6.txt";
	var fileUri:String = document.childExists( filename );
	if( ! fileUri )
	{
		document.createFromUri(filename, content);
	}
	else
	{
		document.uri = fileUri;
		document.editFromUri(content);
	}
	trace( document.uri );
	//ok, let's go
}

what is not working ? the file creation ? it's strange...

Boc89

Tkank's fior reply :-)
I use twice because the first one is for startup, and the second can be later later, when I need to save a file. it can be a fewer days later. When we use the app, it genere several files who can be retrieve with a file explorer. So they need not to be in applicationStorageDirectory

Boc89

The file creation is not working, yes :-(

Boc89

Or do I have to ask permission every time I want to read or save a file in the Documents folder?