Problem with in app purchasing on Google play

FliplineStudios

Hmm, I'm seeing the same flow when making a purchase in one of our apps:

PlayBillingController::makePurchase(): Starting purchase flow
PlayBillingController::makePurchase(): launchBillingFlow(): 0
PlayBillingController::onPurchasesUpdated( 0, [] )

That last line does show that it should be telling your app that a purchase was made, so if you're listening for PurchaseEvent.PURCHASES_UPDATED it should appear there... could you share how you're handling purchases in that listener? Here's roughly how ours are set up:

function onPurchasesUpdated(event:PurchaseEvent):void {

	for each (var purchase:Purchase in event.data) {
					
		if (purchase.transactionState == Purchase.STATE_PURCHASING) {
			//in the process of being purchased, don't do anything.
					
		} else if (purchase.transactionState == Purchase.STATE_DEFERRED) {
			//being deferred right now, don't do anything.
					
		} else if (purchase.transactionState == Purchase.STATE_PURCHASED){
			//this item was purchased!
			
			trace("Item was purchased: "+purchase.productId);
		
			//handle the purchase in your app
			//(TODO HERE)

			//finish purchase:
			InAppBilling.service.finishPurchase(purchase);
			
		} else if (purchase.transactionState == Purchase.STATE_FAILED) {
			//purchase failed:
			
			//(tell the user the purchase failed here)

			//finish purchase:
			InAppBilling.service.finishPurchase(purchase);
							
		} else if (purchase.transactionState == Purchase.STATE_REFUNDED) {
			//purchase refunded
			
			//(handle this in your app if needed)
		
			//finish purchase:
			InAppBilling.service.finishPurchase(purchase);
					
		} else if (purchase.transactionState == Purchase.STATE_RESTORED) {
			//purchase restored:
					
			//(handle this in your app here)
					
			//finish purchase:
			InAppBilling.service.finishPurchase(purchase);
					
		} else if (purchase.transactionState == Purchase.STATE_REMOVED) {
			//purchase removed:
					
			//(handle this in your app here)
			
			//finish purchase:
			InAppBilling.service.finishPurchase(purchase);
					
		} else if (purchase.transactionState == Purchase.STATE_CANCELLED) {
			//purchase cancelled:
			
			//(tell the user they cancelled the purchase here)	
					
			//finish purchase:
			InAppBilling.service.finishPurchase(purchase);
							
		} else if (purchase.transactionState == Purchase.STATE_NOTALLOWED) {
			//not allowed to purchase:
					
			//(tell the user they can't make purchases here)

			//finish purchase:
			InAppBilling.service.finishPurchase(purchase);
						
		}
				
	}
			
}

DanielKotzer

here is the class that is handling the purchase:

`package
{

import com.distriqt.extension.core.Core;
import com.distriqt.extension.inappbilling.BillingService;
import com.distriqt.extension.inappbilling.ErrorCodes;
import com.distriqt.extension.inappbilling.InAppBilling;
import com.distriqt.extension.inappbilling.InAppBillingServiceTypes;
import com.distriqt.extension.inappbilling.Product;
import com.distriqt.extension.inappbilling.Purchase;
import com.distriqt.extension.inappbilling.PurchaseRequest;
import com.distriqt.extension.inappbilling.events.InAppBillingEvent;
import com.distriqt.extension.inappbilling.events.PurchaseEvent;

import flash.display.Sprite;
import flash.events.ErrorEvent;
import flash.events.Event;


//https://docs.airnativeextensions.com/asdocs/inappbilling/com/distriqt/extension/inappbilling/InAppBilling.html
//https://github.com/distriqt/ANE-InAppBilling

public class InAppAndroid extends Sprite implements InAppPurchaseInterface
{
	
	//[Event(name="complete",  type="flash.events.Event.COMPLETE")]
	[Event(name="activate",  type="flash.events.Event.ACTIVATE")]
	//[Event(name="error",  type="flash.events.ErrorEvent)]
	
	public var bookPrice:Array;
	public var bookWasBought:Array;
	
	private var isAndroidIABtSuported:Boolean = false;
	private var FolderName:Array = ["completetalmud","Brachos","Peah","Demai","Kilayim","Sheviit","Trumot","Maasrot","Maaser_Sheni","Challah","Orlah","Bikkurim","Shabbos","Eruvin","Psachim","Shkalim","Yuma","Suka","Beiza","Rosh_Hashana","Tanit","Megila","Moed_Katan","Chagiga","Yebamot","Ktubot","Nedarim","Nazir","Sota","Gitin","Kidushin","Baba_Kama","Baba_Mezia","Baba_Batra","Sanhedrin","Makot","Shvuot","Eduyot","Avoda_Zara","Avot","Horaiot","Zvachim","Menachot","Chulin","Bechorot","Arachin","Tmura","Kritut","Meila","Tamid","Midot","Kanim","Kelim","Oholot","Negaim","Parah","Taharoth","Mikvaot","Nida","Machshirin","Zavim","Tvul_Yom","Yadayim","Oktzin"];
	private var SeriesName:String = "com.company.MainProductName.";
	public var isReady:Boolean = false;
	
	private var ListOfRestoredBooks:String = "";
	
	public var Globals:Object;

	public function InAppAndroid(G:Object)
	{
		Core.init();
		
		bookPrice = new Array();
		bookWasBought = new Array();

		var i:int = 0;
		for (i=0;i<FolderName.length;i++)
		{
			bookPrice[i] = "*";
			bookWasBought[i] = "0";
		}
		
		
		Globals = G;
		
		if (InAppBilling.isSupported)
		{
			if (InAppBilling.service.isServiceSupported(InAppBillingServiceTypes.GOOGLE_PLAY_INAPP_BILLING))
			{
				InAppBilling.service.addEventListener( InAppBillingEvent.SETUP_SUCCESS,         setup_successHandler  );
				InAppBilling.service.addEventListener( InAppBillingEvent.SETUP_FAILURE,         setup_failureHandler );
				
				
				InAppBilling.service.setup(
					new BillingService().setGooglePlayPublicKey( "MIIBIj...  ...wIDAQAB" )
				);
			}
			else
			{
				Globals.debug += "\n Google Play in app billing not supported";	
			}
		}
		else
		{
			Globals.debug += "\n Billing ane not supported";
		}
	}
	
	
	private function setup_successHandler( event:InAppBillingEvent ):void
	{
		
		InAppBilling.service.addEventListener( InAppBillingEvent.PRODUCTS_LOADED,       onProductsLoaded );
		InAppBilling.service.addEventListener( InAppBillingEvent.PRODUCTS_FAILED,       onProductsFailed );
		InAppBilling.service.addEventListener( InAppBillingEvent.INVALID_PRODUCT,       onProductsFailed );
		
		
		InAppBilling.service.addEventListener( PurchaseEvent.PURCHASES_UPDATED, purchases_updatedHandler );
		InAppBilling.service.addEventListener( PurchaseEvent.PURCHASE_FAILED, purchase_failedHandler );
		InAppBilling.service.addEventListener( InAppBillingEvent.FINISH_SUCCESS, finishPurchase_successHandler );
		InAppBilling.service.addEventListener( InAppBillingEvent.FINISH_FAILED, finishPurchase_failedHandler );
		
		InAppBilling.service.addEventListener( InAppBillingEvent.RESTORE_PURCHASES_SUCCESS, restorePurchases_successHandler );
		InAppBilling.service.addEventListener( InAppBillingEvent.RESTORE_PURCHASES_FAILED, restorePurchases_failedHandler );
		
		isReady = true;
		GetProducts();
	}
	
	private function setup_failureHandler( event:InAppBillingEvent ):void
	{
		//Globals.debug += "\n"+event.errorCode;
		trace("sorry, in app billing won't work on this phone!");
	}
	
	
	
	//-------the interface functions------
	
	public function setNewBookList(BookList:Array):void
	{
		FolderName = BookList;
	}
	
	public function GetProducts():void
	{
		
		var productIdList:Array = new Array();
		
		var i:int = 1;
		
		for (i = 0;i<FolderName.length; i++)
		{
			productIdList.push(SeriesName+FolderName[i].toLowerCase());
		}
		
		// Retrieve the product list
		InAppBilling.service.getProducts( productIdList);
		
	}
	
	public function RestorePurchases():void
	{
		ListOfRestoredBooks = ": ";
		// Start the restore process
		InAppBilling.service.restorePurchases();
	}
	
	private var purchasedItemID:String;
	public function purchase(choice:int):void
	{			
		var request:PurchaseRequest = new PurchaseRequest();
		purchasedItemID = request.productId = SeriesName+FolderName[choice].toLowerCase();
		request.quantity = 1;
		
		var success:Boolean = InAppBilling.service.makePurchase( request );
	}
	
	//-------end of interface functions------	
	
	
	private function onProductsLoaded( event:InAppBillingEvent ):void
	{
		if (event.data.length!=0)
		{
			for each(var item:Product in event.data)
			{
				//Globals.debug += "--price--"+item.price;
				var j:int = Id2Num(item.id);
				if (j)
					bookPrice[j] = item.price;
				
				/*
				trace("item id:"+item.itemId);
				trace("title:"+item.title);
				trace("description:"+item.description);
				trace("price:"+item.price);
				*/			
			}
		}
		
		isReady = true;
		
		// event.data will be an Array of Product instances for each product and subscription successfully loaded
		for each (var product:Product in event.data)
		{
			trace( product.toString() );
		}
		
	}
	
	private function onProductsFailed(event:InAppBillingEvent):void
	{
		SendErrorMsg("Error#Loading details Failed  "+event.errorCode);
		trace("Something went wrong loading details: "+event.errorCode);
	}
	
	//-----------------------------
	
	function purchases_updatedHandler( event:PurchaseEvent ):void
	{
		for each (var purchase:Purchase in event.data)
		{
			var massege:String = "";
			massege += "\nProduct ID: "+purchase.productId;
			massege += "\nTransaction Date: "+purchase.transactionDate;
			massege += "\nError: "+purchase.error;
			massege += "\nError Code: "+purchase.errorCode;
			massege += "\nTransaction Id: "+purchase.transactionId;
			massege += "\nTransaction State: "+purchase.transactionState;
			
			
			switch (purchase.transactionState)
			{
				// These transactions are in progress, so don't finish them unless you don't want them to complete
				case Purchase.STATE_PURCHASING:
					SendErrorMsg("PURCHASING!#"+massege);
					break;
				case Purchase.STATE_DEFERRED:
					SendErrorMsg("DEFERRED!#"+massege);
					break;;
				
				// The purchased state should finished after you have delivered the product if applicable
				case Purchase.STATE_PURCHASED:
				{
					trace( "purchase success" );
					
					//
					// If you wish you can add the purchase to your inventory
					// and finish the purchase here
					addPurchaseToInventory( purchase );
					InAppBilling.service.finishPurchase( purchase );
					SendErrorMsg("Purchase Succeeded!#You can now view all pages of the Masechet you have purchased.");
					//
					// Alternatively hold onto this purchase so we can call
					// finish when you've delivered the product
					//
					// You would do this if you are validating the purchase on a server or
					// other operation that is required to complete before the product is delivered
					//_purchases.push( purchase );
					break;
				}
					
				case Purchase.STATE_RESTORED:
					// The originalPurchase property will contain all the 
					// information on the original transaction allowing 
					// you to restore the user's product
					
					addPurchaseToInventory( purchase.originalPurchase );
					InAppBilling.service.finishPurchase( purchase );
					SendErrorMsg("Restore Succeeded!#Restore Previous Purchases has succeeded, you can now view all pages of the books you have previously purchased"+ListOfRestoredBooks);
					
					// Again you could hold on to this purchase and check it against 
					// your application server before calling finishPurchase
					break;
				
				
				
				// For all other states you should handle appropriately and call finish purchase 
				case Purchase.STATE_FAILED:
					SendErrorMsg("FAILED!#"+massege);
					break;
				case Purchase.STATE_REFUNDED:
					SendErrorMsg("REFUNDED!#"+massege);
					break;
				case Purchase.STATE_RESTORED:
					SendErrorMsg("RESTORED!#"+massege);
					break;
				case Purchase.STATE_REMOVED:
					SendErrorMsg("REMOVED!#"+massege);
					break
				case Purchase.STATE_CANCELLED:
					SendErrorMsg("CANCELLED!#"+massege);
					break;
				case Purchase.STATE_NOTALLOWED:
					InAppBilling.service.finishPurchase( purchase );
					SendErrorMsg("NOTALLOWED!#"+massege);
					break;
			}
		}
	}
	
	function purchase_failedHandler( event:PurchaseEvent ):void
	{
		// This transaction failed so you should notify your user and finish the purchase
		var s:String = "purchase failed [" + event.errorCode + "] :: "+ event.message;
		
		if (event.data && event.data.length > 0)
		{
			//s += "Item id: "+event.data[0].productId+"\n";
			InAppBilling.service.finishPurchase( event.data[0] );
		}
		
		switch (event.errorCode)
		{
			// Other error codes...
			case ErrorCodes.ITEM_ALREADY_OWNED:
			{
				s += " Item Already Owned! Click on Restore Previous Purchases";
				// You should use getPurchases() to retrieve the users purchases
				// and then add them as missing from their current inventory
				InAppBilling.service.getPurchases();
				break;
			}
			case ErrorCodes.RESPONSE_CANCELLED:
			case ErrorCodes.USER_CANCELLED:
				s += " Purchase Cancelled!";
				break;
		}
		
		SendErrorMsg("Error#" + s);
		
	}
	
	function finishPurchase_successHandler( event:InAppBillingEvent ):void
	{
		SendErrorMsg("Purchase Succeeded!#You can now view all pages of the Masechet you have purchased.");
	}
	
	function finishPurchase_failedHandler( event:InAppBillingEvent ):void
	{
		SendErrorMsg("Purchase Failed!#"+event.errorCode);
	}
	
	//-----------------------------
	
	
	private function addPurchaseToInventory(purchase:Purchase):void
	{
		var A:Array = purchase.productId.split(".");
		var idName:String = A[A.length-1];
		ListOfRestoredBooks += " "+ Globals.CapitalizeFirstLetter(idName)+",";
		for (var i:int = 0;i<FolderName.length; i++)
		{
			if (FolderName[i].toLowerCase() == idName)
			{
				bookWasBought[i] = "2";
				break;
			}
		}
		
		var eventObject:Event = new Event("activate");
		dispatchEvent(eventObject);
		
	}
	
	
	function restorePurchases_successHandler( event:InAppBillingEvent ):void
	{
		SendErrorMsg("Restore Succeeded!#Restore Previous Purchases has succeeded, you can now view all pages of the books you have previously purchased"+ListOfRestoredBooks);
	}
	
	function restorePurchases_failedHandler( event:InAppBillingEvent ):void
	{
		SendErrorMsg("Error#Loading inventory Failed  "+event.errorCode);
	}
	
	private function Id2Num(name:String):int
	{
		var A:Array = name.split(".");
		var idName:String = A[A.length-1];
		
		for (var j:int=0;j<FolderName.length;j++)
		{
			if (idName==FolderName[j].toLowerCase())
				return j;
		}
		return 0;
	}
	
	private function SendErrorMsg(s:String):void
	{
		var errorEvent:ErrorEvent = new ErrorEvent(ErrorEvent.ERROR, true);
		errorEvent.text = s;
		dispatchEvent(errorEvent);
	}
	
}

DanielKotzer

You say this line shows I got a back a response from the server:
PlayBillingController::onPurchasesUpdated( 0, [] )

but maybe the array is empty?

ma

The 0 is the response code which is "OK" and means the purchases were updated.

There are 3 possible scenarios from that response:

If there were no purchases in the response you will receive a PURCHASE_FAILED event
If there are purchases but they fail validation (i.e. either they are faked or your billing key is wrong) you will receive a PURCHASE_FAILED event
If there are valid purchases you will receive the PURCHASES_UPDATED event

DanielKotzer

ma you should receive a PURCHASES_UPDATED in any case, this is how the new District in app billing ane is working, and even if you got a purchase failed event, I have a handler to deal with it in my code, and I would see a message if such an event was received, now I don't see anything.

FliplineStudios

@DanielKotzer Just a couple things I've noticed in your class is that the purchases_updatedHandler (as well as some of the other handlers) aren't declared as private or public, and are just standalone functions -- not sure if that might be impacting things with handling the purchases correctly. Also, somewhat unrelated, but I believe you should be calling finishPurchase for everything except STATE_PURCHASING and STATE_DEFERRED, and some of your cases near the bottom (FAILED, REFUNDED, RESTORED, REMOVED, CANCELLED) are missing the finishPurchase call. Might be worth a try to update those and set the handlers to be private methods to see if that makes a difference.

DanielKotzer

FliplineStudios You do a finishpurchase only for a good purchase, not for a failed one, the user might want to pay you directly, so you should say when the purchase is final or else it is canceled after 3 days. the missing of the private declaration can't be the problem, remember this code is working fine on another product I have.

FliplineStudios

DanielKotzer The docs do mention that you need to call finishPurchase on anything that's not "PURCHASING" or "DEFERRED". Finishing doesn't necessarily mean it was a successful purchase, just that your app has done whatever it needed to do with that attempted purchase, whether there was an error, or cancelled, or not allowed, or successful (your own purchase_failedHandler also finishes failed purchases):

// For all other states you should handle appropriately and call finish purchase 
            case Purchase.STATE_FAILED:
            case Purchase.STATE_REFUNDED:
            case Purchase.STATE_RESTORED:
            case Purchase.STATE_REMOVED:
            case Purchase.STATE_CANCELLED:
            case Purchase.STATE_NOTALLOWED:
                InAppBilling.service.finishPurchase( purchase );
                break;

As a rule it is important that you call finishPurchase() when you have completed the purchase and either handled the error or deployed the product to the user's inventory.

Not really sure what else the problem could be, I was just pointing out parts of your Class that didn't fully match how the docs and example files are set up, in case those might be problem areas. Very strange that the same code works in another app but not this one, do they both have the same up-to-date ANEs and same manifest additions in the application XML?

DanielKotzer

I tried to send a message when the PurchaseEvent.PURCHASES_UPDATED happens with the number of items in the event.data.length, but nothing happens, this event is simply not happening, the server seems to sent it though:

09-02 23:17:15.897 8663 8663 I com.distriqt.InAppBilling: InAppBillingContext::onActivityStateChanged( PAUSED ) android.intent.action.MAIN 09-02 23:17:29.386 8663 8663 I com.distriqt.InAppBilling: InAppBillingContext::onActivityStateChanged( RESUMED ) android.intent.action.MAIN **09-02 23:17:29.452 8663 8663 I com.distriqt.InAppBilling: PlayBillingController::onPurchasesUpdated( 0, [] )** 09-02 23:17:29.457 8663 8663 I com.distriqt.InAppBilling: PlayBillingUtils::encodeReceipt( com.jewishsoftware.mastermishna.sheviit ) 09-02 23:17:51.670 8663 8663 I com.distriqt.InAppBilling: InAppBillingContext::onActivityStateChanged( PAUSED ) android.intent.action.MAIN 09-02 23:17:51.854 8663 8663 I com.distriqt.InAppBilling: InAppBillingContext::onActivityStateChanged( STOPPED ) android.intent.action.MAIN

So I do get the available products and their prices from the server properly, I do get an event when I do restore purchases, but no purchases are restored because no purchase was ever successful, also I don't know if this message is coming from the product update event or from the InAppBillingEvent.RESTORE_PURCHASES_SUCCESS event. But there seems to be a communication with the server.

What am I supposed to do next?

FliplineStudios

DanielKotzer So I do get the available products and their prices from the server properly, I do get an event when I do restore purchases, but no purchases are restored because no purchase was ever successful, also I don't know if this message is coming from the product update event or from the InAppBillingEvent.RESTORE_PURCHASES_SUCCESS event. But there seems to be a communication with the server.

If you're getting other events successfully from the server (available products and prices), that would lead me to believe there's something wrong with your listener for the PURCHASES_UPDATED event, either it's having an issue accessing the handler, or there's some error in your code in the handler causing the whole for-each loop to fail. I'd maybe try just commenting out your whole purchases_updatedHandler and creating a new one just to test that it's able to receive communication at all:

private function purchases_updatedHandler( event:PurchaseEvent ):void {
      trace("Update Handler Working");
 }

Then if you're seeing the trace, you know it's communicating with the server correctly and there's just something in your code that's hanging things up, and slowly work towards rebuilding each case in your handler.

DanielKotzer

Maybe there is another ANE that works on Flash Builder 4.7 and supports billing library version 3? if they both will have the same problem something has to be wrong on the server side...
Maybe I need an ANE that supports billing library version 4? maybe this has become a requirement lately? Some times things like that happen on google plays server, it is not consistent sometimes...

DanielKotzer

FliplineStudios The docs do mention that you need to call finishPurchase on anything that's not "PURCHASING" or "DEFERRED". Finishing doesn't necessarily mean it was a successful purchase

thank you for this information, I'll fix it.

DanielKotzer

FliplineStudios Then if you're seeing the trace,

How do I see the trace? using the command line you showed me:
D:\FlashBuilder\new_33.1.1.554\lib\android\bin>adb logcat com.distriqt.InAppBilling:V *:S

ma

It could also be important to check where and how you are attaching the listener and that the InAppAndroid class you are using isn't getting garbage collected or something along those lines?

FliplineStudios

DanielKotzer If you're using remote debugging with a debug build you should be able to see your trace statements, or if you're not using a debugger you can instead use adb logcat while testing on your device, though you'd need a somewhat different command:

https://help.adobe.com/en_US/air/build/WSfffb011ac560372f-5d0f4f25128cc9cd0cb-7ff8.html

Make sure you've published the SWF with debugging enabled (and I believe you need to use "apk-debug" as the target for publishing the APK as well?), and then you can use your app's application ID with logcat. In this example it will show your app's trace statements, and also the InAppBilling logging, but will silence everything else:

adb logcat air.com.your.app.here:V com.distriqt.InAppBilling:V *:S

And just to clarify, with this debugging/tracing test this would be for a separate debug build that you're making and installing directly on your device with adb, not a build that you'd be uploading to Google Play (once they've reviewed a build in the alpha track, you should be able to access any of the in-app purchase SKUs from local test builds and don't have to keep uploading, though they can take a day or so before they're available in your app)

DanielKotzer

I did find out a problem that could make a difference between the 2 products, I'm testing it but when I upload an Alpha build for closed test on Google play it takes them a week to review this build, so it is very slowly.
The difference I found is that one app has a list of in app products it asks for with:
InAppBilling.service.getProducts( productIdList);
and all these products were created by me, and are ready for sale,
While the other product that is not working, has a list of 62 products and only about 20 where made.
This wasn't a problem before I was using the district ANE, because if I was asking for a product that didn't exist it wasn't sending anything back but now you get an error message which might interrupt the purchasing process.
And another thing I found out is that I do get one item in return:

function purchases_updatedHandler( event : PurchaseEvent ):void { SendErrorMsg("NUMBER OF ITEMS:#"+event.data.length);...

this gives me 1, but for some reason it is not activating anything in the switch case code, so I did something else to see what are the details of this item I'm getting in return:
`function purchases_updatedHandler( event😛urchaseEvent ):void
{
//SendErrorMsg("NUMBER OF ITEMS:#"+event.data.length);

		for each (var purchase:Purchase in event.data)
		{
			var massege:String = "";
			massege += "\nProduct ID: "+purchase.productId;
			massege += "\nTransaction Date: "+purchase.transactionDate;
			massege += "\nError: "+purchase.error;
			massege += "\nError Code: "+purchase.errorCode;
			massege += "\nTransaction Id: "+purchase.transactionId;
			massege += "\nTransaction State: "+purchase.transactionState;
			
			SendErrorMsg("ITEM INFO:#"+massege);
			
			switch (purchase.transactionState)
			{
				// These transactions are in progress, so don't finish them unless you don't want them to complete
				case Purchase.STATE_PURCHASING:
					SendErrorMsg("PURCHASING!#"+massege);
					break;...`

Though now I have to wait a week for Google Play team to review this Alpha build and make it available, so I can test it and see what I'm getting.

DanielKotzer

Issue was resolved.
this function had a problem:
addPurchaseToInventory( purchase );
it was using a global function that existed in one app, but not on the other and it was causing the code to stop running, fixed it and everything is OK.
What can I do, that is programing, sometimes a small mistake can cause a lot of trouble...
Thank you for your time.

Interestingly, after I opened my device for debugging, it was running the billing process even on a version I was running on an Android device connected to my Desktop while FB was running. I don't know if this is because I had an Alpha testing build uploaded with the same version number, but it did run the billing process just without charging my credit card, jus by clicking on the Buy now button, I was receiving an update purchase event. So in the end I've learned many new things on who to debug the billing process. Thank you very much for the help.

FliplineStudios

That's great to hear, glad you got it figured out!