How to create a standalone exe?

Ger

Does anyone know how to create a standalone exe of Air/Starling without the user having to install AIR? Is there a captive exe option?

On Adobe's website I read how to create a native exe but it says that it will try to download and install air and the exe will not work if there is no internet connection. So that is not what I am looking for.

Ger

Here is what Adobe says:

"If the required version of Adobe AIR is not already installed on the machine, the installer downloads it from the network and installs it first. If there is no network connection from which to obtain the correct version of Adobe AIR (if necessary), installation fails."

http://help.adobe.com/en_US/air/build/WS789ea67d3e73a8b22388411123785d839c-8000.html

Pointless

I haven't done it.
But I think you would create a "Signed application with captive runtime" and then use a tool like wix to repackage it and create an installer.

Like detailed here:
http://www.adobe.com/devnet/air/articles/customize-setup-for-AIR-app-with-captive-runtime.html

DrNeroCF

This has got to be the single strangest attribute of AIR to me. Why is this not the first option for packaging an exe? I can make a single app for OS X, and if you install the exe, you an go to your program files and grab the exe for testing, but that won't work if the user doesn't have AIR installed. There's the projectors, but that seems to have the same keyboard bug as the Flash Player does, at least on the Mac side (Flash Player in Windows would cause ShadowPlay to start stuttering, though).

The Projector seems to have good enough performance on the PC side, but I'd like to hear if anyone's familiar with the best, highest performance method of creating a simple exe.

Ger

I almost got it working. I created a captive run time with Flash Develop. And now I just need to be able to add directories to NSIS to create the exe. But I'm having hard time finding how to do that.

Does any one here know how to add a directory with the directory being created with all it's files in it, instead of just adding files one by one to a NSIS script? Or does any one have an example NSIS file there are using for Air apps with NSIS?

When I am done I will come back here and write out all the steps.

mistergreen

The Flash pro/cc app can make exe with the AIR runtime. There is an option to embed AIR.

Was looking around here
http://www.adobe.com/devnet/air/articles/air3-install-and-deployment-options.html

You can do it through command line.

joshtynjala

EDIT: See Ger's post below to learn how to do it.

Does any one here now how to add a directory with the directory being created with all it's files in it, instead of just adding files one by one to a NSIS script?

When I created an NSIS installer, I could not find a way to simply include an entire directory of files. I had to include each individual file separately. This is basically how it looks when I include all of my files:

SetOutPath "$INSTDIR"
File "MyApp\MyApp.exe"
File "MyApp\MyApp.swf"
File "MyApp\mimetype"
SetOutPath "$INSTDIR\META-INF"
File "MyApp\META-INF\signatures.xml"
SetOutPath "$INSTDIR\META-INF\AIR"
File "MyApp\META-INF\AIR\application.xml"
File "MyApp\META-INF\AIR\hash"
SetOutPath "$INSTDIR\icons"
File "MyApp\icons\icon16.png"
File "MyApp\icons\icon32.png"
File "MyApp\icons\icon48.png"
File "MyApp\icons\icon128.png"
SetOutPath "$INSTDIR\Adobe AIR\Versions\1.0"
File "MyApp\Adobe AIR\Versions\1.0\Adobe AIR.dll"
SetOutPath "$INSTDIR\Adobe AIR\Versions\1.0\Resources"
File "MyApp\Adobe AIR\Versions\1.0\Resources\WebKit.dll"
File "MyApp\Adobe AIR\Versions\1.0\Resources\CaptiveAppEntry.exe"

I should mention that I wrote this installer script several years ago, though, and I don't have experience with newer NSIS updates. Maybe it's possible to copy a directory and all of its files now.

tuarua

If you are considering an alternative to NSIS, I use Inno Setup. It can thankfully include folders. It also does other things like dependency checking for .NET etc if you need/use them.

I use it to package an AIR app here.

https://github.com/tuarua/WebViewANE/tree/master/win_installer

Ger

Thanks a lot Josh. I will try that now.

I did try Inno, but caused my antivirus to pause the install to scan it, which NSIS did not do. Well it did it with a simple NSIS example as well, but not a complex NSIS example for some reason. I will try to stick with NSIS.

Ger

Josh did you apply for any certificate to get trusted installer or something?

joshtynjala

You should be able to use the same certificate to sign your installer that you use to sign your AIR app.

You can use the signtool.exe from Microsoft to sign your installer.

signtool.exe sign /f path/to/my-certificate /p my-certificate-password MyInstaller.exe

I think signtool.exe is in some kind of Windows SDK that you may need to download first. It's been a while since I set up a new machine, so I don't remember exactly what I installed last time.

Ger

Thanks again Josh, I will download that.

I found another way to include the whole project files in 1 line of code rather than creating directories and adding files 1 by 1. I remembered another game engine, I used a few years ago, created a NSIS script. I had a look at that and found that fantastic line. I tested it and it works!

file /r "C:\myAppLocatoin\project\*.*"

That will do everything

And to uninstall it:

# Remove files and uninstaller (everything)
        rmDir /r $INSTDIR

But it leaves the Company folder. Everything else is gone. I can't figure out how to remove the empty company folder. The installer creates companyName/AppName/ and after uninstall what is left is just the companyName folder (empty inside).

Ger

For anyone else that wants to know how.

HOW I DID IT. WHAT I DID SO FAR THAT WORKS.

1)In FlashDevelop open the Packager.bat file in the BAT folder.

2) Change
call adt -package %OPTIONS% %SIGNING_OPTIONS% %OUTPUT% %APP_XML% %FILE_OR_DIR%
to
call adt -package %OPTIONS% %SIGNING_OPTIONS% -target bundle %OUTPUT% %APP_XML% %FILE_OR_DIR%

3) In your windows folder double click on the PackageApp.bat file. It now creates an air project folder. This will be used with NSIS to create the installer.

4) Install NSIS: http://nsis.sourceforge.net/Main_Page

5) Save the code below in a text file and save it as anything you want with the extension .nsi and then compile it in NSIS. Presto you're installer file is ready.

NOTE: I have a license reference in the code there. You can create that next to your NSIS file. Just create a text file called license.rtf. If you include it in your project directory then make sure to insert the directory address for that in the NSIS code.

# This installs two files, app.exe and logo.ico, creates a start menu shortcut, builds an uninstaller, and
# adds uninstall information to the registry for Add/Remove Programs

# To get started, put this script into a folder with the two files (app.exe, logo.ico, and license.rtf -
# You'll have to create these yourself) and run makensis on it

# If you change the names "app.exe", "logo.ico", or "license.rtf" you should do a search and replace - they
# show up in a few places.
# All the other settings can be tweaked by editing the !defines at the top of this script
!define APPNAME "My App"
!define COMPANYNAME "My Company"
!define DESCRIPTION "A short description goes here"
# These three must be integers
!define VERSIONMAJOR 1
!define VERSIONMINOR 1
!define VERSIONBUILD 1
# These will be displayed by the "Click here for support information" link in "Add/Remove Programs"
# It is possible to use "mailto:" links in here to open the email client
!define HELPURL "http://..." # "Support Information" link
!define UPDATEURL "http://..." # "Product Updates" link
!define ABOUTURL "http://..." # "Publisher" link
# This is the size (in kB) of all the files copied into "Program Files"
!define INSTALLSIZE 7233

RequestExecutionLevel admin ;Require admin rights on NT6+ (When UAC is turned on)

InstallDir "$PROGRAMFILES\${COMPANYNAME}\${APPNAME}"

# rtf or txt file - remember if it is txt, it must be in the DOS text format (\r\n)
LicenseData "license.rtf"
# This will be in the installer/uninstaller's title bar
Name "${COMPANYNAME} - ${APPNAME}"
Icon "logo.ico"
outFile "my-installer.exe"

!include LogicLib.nsh

# Just three pages - license agreement, install location, and installation
page license
page directory
Page instfiles

!macro VerifyUserIsAdmin
UserInfo::GetAccountType
pop $0
${If} $0 != "admin" ;Require admin rights on NT4+
        messageBox mb_iconstop "Administrator rights required!"
        setErrorLevel 740 ;ERROR_ELEVATION_REQUIRED
        quit
${EndIf}
!macroend

function .onInit
	setShellVarContext all
	!insertmacro VerifyUserIsAdmin
functionEnd

section "install"
	# Files for the install directory - to build the installer, these should be in the same directory as the install script (this file)
	setOutPath $INSTDIR
	# Files added here should be removed by the uninstaller (see section "uninstall")
	file "logo.ico"
	file /r "C:\myAppLocation\project\*.*"

	# Add any other files for the install directory (license files, app data, etc) here

	# Uninstaller - See function un.onInit and section "uninstall" for configuration
	writeUninstaller "$INSTDIR\uninstall.exe"

	# Start Menu
	createDirectory "$SMPROGRAMS\${COMPANYNAME}"
	createShortCut "$SMPROGRAMS\${COMPANYNAME}\${APPNAME}.lnk" "$INSTDIR\NewProject.exe" "" "$INSTDIR\logo.ico"

	# Registry information for add/remove programs
	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${COMPANYNAME} ${APPNAME}" "DisplayName" "${COMPANYNAME} - ${APPNAME} - ${DESCRIPTION}"
	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${COMPANYNAME} ${APPNAME}" "UninstallString" "$\"$INSTDIR\uninstall.exe$\""
	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${COMPANYNAME} ${APPNAME}" "QuietUninstallString" "$\"$INSTDIR\uninstall.exe$\" /S"
	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${COMPANYNAME} ${APPNAME}" "InstallLocation" "$\"$INSTDIR$\""
	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${COMPANYNAME} ${APPNAME}" "DisplayIcon" "$\"$INSTDIR\logo.ico$\""
	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${COMPANYNAME} ${APPNAME}" "Publisher" "$\"${COMPANYNAME}$\""
	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${COMPANYNAME} ${APPNAME}" "HelpLink" "$\"${HELPURL}$\""
	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${COMPANYNAME} ${APPNAME}" "URLUpdateInfo" "$\"${UPDATEURL}$\""
	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${COMPANYNAME} ${APPNAME}" "URLInfoAbout" "$\"${ABOUTURL}$\""
	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${COMPANYNAME} ${APPNAME}" "DisplayVersion" "$\"${VERSIONMAJOR}.${VERSIONMINOR}.${VERSIONBUILD}$\""
	WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${COMPANYNAME} ${APPNAME}" "VersionMajor" ${VERSIONMAJOR}
	WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${COMPANYNAME} ${APPNAME}" "VersionMinor" ${VERSIONMINOR}
	# There is no option for modifying or repairing the install
	WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${COMPANYNAME} ${APPNAME}" "NoModify" 1
	WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${COMPANYNAME} ${APPNAME}" "NoRepair" 1
	# Set the INSTALLSIZE constant (!defined at the top of this script) so Add/Remove Programs can accurately report the size
	WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${COMPANYNAME} ${APPNAME}" "EstimatedSize" ${INSTALLSIZE}
sectionEnd

# Uninstaller

function un.onInit
	SetShellVarContext all

	#Verify the uninstaller - last chance to back out
	MessageBox MB_OKCANCEL "Permanantly remove ${APPNAME}?" IDOK next
		Abort
	next:
	!insertmacro VerifyUserIsAdmin
functionEnd

section "uninstall"

	# Remove Start Menu launcher
	delete "$SMPROGRAMS\${COMPANYNAME}\${APPNAME}.lnk"
	# Try to remove the Start Menu folder - this will only happen if it is empty
	rmDir "$SMPROGRAMS\${COMPANYNAME}"

	# Remove files
	delete $INSTDIR\Project.exe
	delete $INSTDIR\logo.ico

	# Always delete uninstaller as the last action
	delete $INSTDIR\uninstall.exe

	# Remove files and uninstaller (everything)
        rmDir /r $INSTDIR

        # Remove directories used
        rmDir "$SMPROGRAMS\${APPNAME}"

	# Try to remove the install directory - this will only happen if it is empty
	rmDir $INSTDIR

	# Remove uninstaller information from the registry
	DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${COMPANYNAME} ${APPNAME}"
sectionEnd

therobby3

Hmm, sounds like alot of work here. =o? For me this is extremely simple. I use Adobe Animate CC along with Flash Develop to compile my games. In AnimateCC all I have to do is go to "AIR settings" and next to "Output as:" I click "Windows installer". I click "publish" and boom done, an exe is made that doesn't require AIR to run.

joshtynjala

The "Windows installer" option in Animate CC will not produce a standalone captive runtime app. The shared runtime will be bundled in the Windows installer, and if the user doesn't have it already, it will be installed alongside your app.

mistergreen

@therobby3
I think he wants to create an install widget.

Ger

I ran the signtool on exe and it signed it, no problems.

But when I ran verify by the signtool

It says "File is not timestamped".

"SignTool Error: A certificate chain processed, but terminated in a root certificate which is not trsuted by the trust provider."

joshtynjala

Is it a self-signed certificate, or a certificate that you purchased? That seems like the kind of error you might see from a self-signed certificate. Although, I'm no expert here.

Ger

The p12 cert that FlashDevelop creates. I looked at paid certs. About $170 per year.

mrpinc

The p12 that FD generates is not good enough, it's not signed by an authority. You need a paid one.