Feathers Input forget focus on browser Alt+Tab

clozertou

Hi there,
When we start typing few words in text input and then alt+tab and then come back feathers then we have to click again to focus the input and resume typing.
Any way we can maintain the focus?

joshtynjala

I think Flash Player removes focus from a focused TextField when the browser goes into the background. That causes the TextInput to lose focus.

clozertou

So how can we fix that?
Any suggestions

joshtynjala

No clue. I assume it would require changes to Flash Player.

bslote

One way to hack it would be storing a reference to the currently focused TextInput, and then we you detect that your app has returned to the foreground, call setFocus() on the TextInput ref you stored.

clozertou

need some generic solution as we have dozens of screens with many text components

joshtynjala

A generic solution may be possible. Every flash.events.EventDispatcher in an app will dispatch Event.DEACTIVATE when Flash Player loses focus (and Event.ACTIVATE when it gains focus again). Assuming that you're using the Feathers FocusManager, its focus property may not be null yet when Event.DEACTIVATE is dispatched. That will allow you to save the focused object in a variable. When Event.ACTIVATE is dispatched, restore the focus by setting FocusManager.focus to the saved object.

Starling.current.nativeStage may be a good place to listen for Event.ACTIVATE and Event.DEACTIVATE.

If FocusManager.focus is null on Event.DEACTIVATE, then there may not be a good way to do it.

clozertou

Can you please try implementing a generic solution in Feathers itself?

timwjohn

Here's my solution. Code added to the application itself:

private var pendingFocusObject:IFocusDisplayObject;

override protected function initialize():void
{
    super.initialize();

    FocusManager.setEnabledForStage(stage, true);
    
    stage.starling.nativeStage.addEventListener(flash.events.Event.ACTIVATE, stage_activateHandler);
    stage.starling.nativeStage.addEventListener(flash.events.Event.DEACTIVATE, stage_deactivateHandler);
}

private function stage_deactivateHandler(event:flash.events.Event):void
{
    var focusManager:IFocusManager = FocusManager.getFocusManagerForStage(stage);
    if (focusManager == null)
    {
        return;
    }
    pendingFocusObject = focusManager.focus;
}

private function stage_activateHandler(event:flash.events.Event):void
{
    var focusManager:IFocusManager = FocusManager.getFocusManagerForStage(stage);
    var focusObject:IFocusDisplayObject = pendingFocusObject;
    pendingFocusObject = null;
    if (focusManager == null || focusObject == null || focusObject.stage == null || focusObject.isFocusEnabled)
    {
        return;
    }
    focusManager.focus = focusObject
}